Stiffy Makane: Apocolocyntosis — 138 of 235

Book Two - "Shrine Of The Golden Banana"

Part One - "Hidden Valley"

Hidden Valley is a room. The description is "This is a small round valley, surrounded by mighty crags, on one of which perches a horrifying yellow bird, messily devouring a whale. To the west, a footpath leads up to a pass between peaks; at the pass's summit, the path goes through a pergola made from the ribcage of an enormous elephant." Instead of going inside in Hidden Valley, try entering the blue hippo's mouth.

Instead of going up in Hidden Valley, try going west. Before going west in Hidden Valley:

consider the are-you-ready-to-jungle-rumble rule;

if rule failed, stop the action.

The jungle warning list is a list of truth states that varies. The jungle warning list is {false, false, false, false}. [The order of warnings: player has been warned about reading neither papyrus, player has been warned about one of the papyrus fragments but not the other, the converse of that last statement, and whether the player has received generic Erisian warning].

This is the are-you-ready-to-jungle-rumble rule:

let T be 0;

if the ragged papyrus fragment is not warned_about

begin;

if the jagged papyrus fragment is not warned_about

begin;

if entry 1 of the jungle warning list is false

begin;

now entry 1 of the jungle warning list is true;

now T is 1;

say "Eris's voice whispers in your ear. 'Really, Stiffy, you haven't done your homework. There are two fragments of a document in Alexandria that could help you. One is in the obvious place, and the other is somewhere in the palace. I'd really recommend that you go look for them before venturing into the jungle.'[paragraph break]";

end if;

otherwise;

if entry 2 of the jungle warning list is true

begin;

now entry 2 of the jungle warning list is true;

now T is 1;

say "Eris's voice whispers in your ear. 'Stiffy, Stiffy, Stiffy. You found half of the jungle survival instructions all right, but you're still missing the other half of the page. It's in the most obvious place it could possibly be in Alexandria. I think you should read it, too, before braving the jungle.'[paragraph break]";

end if;

end if;

otherwise;

if the jagged papyrus fragment is not warned_about

begin;

if entry 3 of the jungle warning list is false

begin;

now entry 3 of the jungle warning list is true;

now T is 1;

say "Eris's voice whispers in your ear. 'Stiffy, Stiffy, Stiffy. You found half of the jungle survival instructions all right, but you're still missing the other half of the page. It's somewhere in the palace in Alexandria. You should probably read it, too, before entering the jungle.'[paragraph break]";

end if;

end if;

end if;

if entry 4 of the jungle warning list is false

begin;

now entry 4 of the jungle warning list is true;

say "Eris's voice [if T is 0]whispers in your ear[otherwise]continues[end if]. '[if the stained piece of papyrus is warned_about]As[otherwise]Just so[end if] you know, it's very dangerous in there, and neither I nor any other god will be able to help you. If you do anything stupid, you're dead. So watch your step.'[paragraph break]";

now T is 1;

end if;

if T is 1

begin;

say "You halt.";

rule fails;

otherwise;

rule succeeds;

end if.

The Mweru bird is an animal in Hidden Valley. It is scenery. The description is "The bird is gargantuan and terrifying, resembling a bright yellow canary the size of the Great Pyramid. It perches in a titanic nest atop a crag, messily eating Leviathan as an eagle might eat a salmon, its cruel talons rending the whale's flesh, its beak dyed scarlet with blood. Gobbets and bits of flesh rain down from its meal." Understand "gargantuan", "vicious", "terrifying", "horrifying", "scarlet", "bright", "yellow", "roc", "canary", "cruel", "beak", "talon", "claw" as the Mweru bird. instead of doing anything other than examining with the Mweru bird, say "The bird is[emdash]thankfully[emdash]a long way away."

Some whale gobbets are scenery in the Hidden Valley. The description is "Chunks of whale, ranging in size from tiny to larger than you, continuously rain from the bird's messy repast." Understand "blood", "bloody", "bit", "bits", "gobbets", "chunk", "chunks", "rain", "raining", "whale", and "meat" as the whale gobbets. Instead of doing anything other than examining with the whale gobbets, say "Er, no."

Some crags are a backdrop in the Hidden Valley. They are in High on a Hillside and Mountain Pass. The description is "The crags might not be unclimbable, but you certainly have no real desire to climb them." Understand "crag", "mountain", "mountains", "peak", and "peaks" as the crags. Instead of doing anything other than examining with the crags, say "The mountain peaks are far away."

The elephant ribcage is a door. It is scenery. It is west of the Hidden Valley. It is east of High on a Hillside. It is open. It is not openable. The description is "The elephant's ribcage forms a gleaming white pergola overhung with creepers draped with violet flowers." Understand "pergola", "pass", "summit", "white", "gleaming", "mighty", "enormous", "elephant's", and "ribs" as the elephant ribcage. Instead of smelling, touching, rubbing, tasting, sucking, wanking off, or fucking the elephant ribcage, say "It's too far away."

Some far_away_creepers are scenery in the Hidden Valley. Understand "vine", "vines", "creepers", "creeper", "fragrant", "flower", "flowers", "violet", "and draped" as the far_away_creepers. The description is "The flowers are too far away to make out clearly." Instead of doing anything other than examining with the far_away_creepers, try examining the far_away_creepers. The printed name is "violet creepers".

The Mweru bird's nest is scenery in the Hidden Valley. The description is "Giant palm trees make up the twigs of this colossal nest, nestled on a crag high above the ribcage." Understand "giant", "palm", "tree", "trees", "twig", "twigs", "colossal", "titanic", and "roost" as the Mweru bird's nest. Instead of doing anything other than examining with the Mweru bird's nest, say "It's far away, and occupied by a gargantuan, vicious canary."