Stiffy Makane: Apocolocyntosis — 212 of 235

Book Two - "Geography"

Near The Tree Line is a mountain room in Olympic Slopes. It is west of Prionia. The description is "You have come to a fork in the mountain path. Although there are sparse trees around you, you can see that they cease not far above. A steep trail ascends to the north, and a slightly more gentle one to the south. The descent to the logging camp is to your east. The cloud-shrouded summit is above you almost directly west." Instead of going down in Near The Tree Line, try going east. Instead of going west in Near The Tree Line, try going up. Instead of going up in Near The Tree Line, say "Trails ascend both north and south." Instead of going down in Near The Tree Line, try going east. Before going south in Near The Tree Line, say "The trail follows the tree line south for a while, and then turns west and heads straight up a barren and snowy ridge into the cloudbank."

Olympic Ridge is a mountain room in Olympic Slopes. It is south of Near The Tree Line. The chill factor is 20. The description is "The wind is bitter here. Snow crunches underfoot, and visibility is nearly zero. The trail descends to the tree line to the north; a steep and treacherous route leads across a vast open cirque to your west occasionally visible in gaps in the fog, and the trail proceeds along the ridge to your south." Instead of going down in Olympic Ridge, try going north. Instead of going up in Olympic Ridge, say "Trails ascend to the west and south."

Saddle is a mountain room in Olympic Slopes. It is south of Olympic Ridge. "Wind whips past you, chilling your exposed flesh. A shallow descent along a snowy ridge lies to your south; the trail drives up a steep ridge to your west, and you can descend to the north." Before going south in Saddle, say "The trail descends for a while, reaches another saddle point, and then ascends steeply." The chill factor is 25. Instead of going up in Saddle, try going west. Instead of going down in Saddle, say "Both the northern and southern trails descend."

Southern Peak is a mountain room in Olympic Slopes. It is south of Saddle. The description is "You stand atop a peak of Olympus, although, alas, not [italic type]the[roman type] peak. The icy wind here is brutal. The ridge dips slightly to your west and then ascends further into the cloudbank. To your east a narrow declivity descends precipitously, and another ridgeline leads off to your north." Instead of going up in Southern Peak, try going west. The chill factor is 40. Instead of going down in Southern Peak, say "The northern path descends, and so, more dramatically, does a canyon to your east." Instead of going east in Southern Peak:

if the walking stick is held by the player

begin;

say "You begin the steep descent to the east; its pitch increases quickly and before long you lose your footing in the snow. After tumbling several hundred yards, you manage to arrest your fall with the aid of your walking stick, which, sadly, snaps while saving you. However, you find you have nearly reached the treeline, and after a few more hours of scrambling and bushwhacking you find yourself back near the logging camp.";

remove the walking stick from play;

move the player to Prionia;

otherwise;

say "You begin the steep descent to the east; its pitch increases quickly and before long you lose your footing in the snow. You flail your arms wildly, but are unable to stop your fall. You tumble and tumble, and eventually plunge over a precipice to your death.";

end the story saying "You have fallen off a mountain.";

end if.

Skolio is a mountain room in Olympic Slopes. It is west of Southern Peak. The description is "You stand exposed on one of the summits of Olympus, the raging wind clawing at your eyeballs. This, however, is not [italic type]the[roman type] summit. The ridgeline descends to both your east and your north." The chill factor is 50. Instead of going up in Skolio, say "There's no up here." Instead of going down in Skolio, say "Either east or west would work to descend." Before going west in Skolio, say "The ridge descends for a little while and then begins to climb again."

Skala is a mountain room in Olympic Slopes. It is north of Skolio. It is west of Olympic Ridge. The chill factor is 30. "This is a promontory on the long ridgeline that runs east and north. A steep ridge descends to your west as well. The trail ascends steeply, over treacherous ground, to the north, and dips-and-then-ascends to the east." Instead of going up in Skala, say "East and north both ascend." Instead of going down in Skala, try going west. Before going north in Skala:

if the walking stick is held by the player

begin;

say "Several times on the ascent the talus slope begins to give way, but by planting your walking stick and vaulting aside, you manage not to be swept away.";

otherwise;

say "You start up the slope, but only a few dozen yards up, your footing gives way under you as the rocks begin to slide. You try to keep your balance, but lack anything to give you better purchase, and you are crushed in the ensuing avalanche.";

end the story saying "You have been killed in a rockslide.";

end if;

Cirque is a mountain room in Olympic Slopes. It is north of Near the Tree Line. The chill factor is 25. The description is "High up inside an enormous bowl, you are slightly sheltered from the bitter wind. A terrifyingly steep ledge ascends to the north, and a more moderate trail climbs to your east. A treacherous route descends to the south." Instead of going up in Cirque, say "Both northern and southern routes ascend." Instead of going down in Cirque, try going south. Instead of going east in Cirque:

say "Only a few hundred yards along the southern route, the ice underneath you suddenly gives way. You begin to slide down the face of the snow-covered bowl. [run paragraph on]";

if the walking stick is held by the player

begin;

say "Somehow, after a terrifying tumble, you manage to jam your stick into a crevice past which you are hurtling, and although the stick snaps, you are slowed enough that you are not dashed to pieces when you cartwheel through the treeline and impact a small pine. A few hours' limping brings you back to the logging camp.";

remove the walking stick from play;

move the player to Prionia;

otherwise;

say "You pick up inexorable speed as you fall downhill, unable to arrest your fall, until you are stopped, fatally, by the pines at the treeline.";

end the story saying "You have been dashed to pieces on a pine tree.";

end if.

Perilous Ledge is a mountain room in Olympic Slopes. It is north of Cirque. It is west of Saddle. Instead of going down in Perilous Ledge, say "You could descend either south or east.". The description is "A steep and narrow ledge descends to the south and east. An almost vertical scramble ascends to your west. To the north there is nothing but thousands of feet of air." The chill factor is 35. Instead of going up in Perilous Ledge, try going west. Before going west in Perilous Ledge:

if the walking stick is held by the player

begin;

say "With the aid of your trusty walking stick, you are able to claw your way up the icy chute.";

otherwise;

say "You get about a hundred yards up the icy chute, and then your frostbitten fingers slip off a handhold. Lacking any means to arrest your fall, flailing and screaming, you cartwheel into the void below.";

end the story saying "You have fallen to your death.";

end if.

Scenery_scramble is scenery in Perilous Ledge. The printed name is "ravine". Scenery_scramble can be enterable. It is enterable. The description is "A horribly steep scramble ascends a ravine to the west, into thick clouds." Understand "scramble", "steep", "ravine", "chute", "gully", "canyon", and "chimney" as the scenery_scramble. Instead of entering the scenery_scramble, try going west. Instead of climbing the scenery_scramble, try going west. Instead of doing anything other than examining, entering, or climbing the scenery_scramble, say "About all you can do with the ravine is attempt to climb it."