Stiffy Makane: Apocolocyntosis — 223 of 235
One of the Bruces and Drunken Bastard
Book Three - "Eris (Again)"
Table of Erisian Chatter
| topic | reply | summary | turn stamp |
| "me/myself/Mentula/Macanus/Stiffy/Macane/Lucius" or "Stiffy Makane" or "Mentula Macanus" or "Lucius Macanus Mentula" | "'Stiffy, you've done magnificently. Just one more task, and then you will receive your reward.'" | "she told you you only had one more thing to do before you would be rewarded" | -- |
| "Argus" | "'That son-of-a-whore Argus is gonna get a plantain in the pooper, if I have anything to say about it.'" | "Argus is headed for a rectal encounter with the Golden Banana" | -- |
| "Caesar/Julius" or "Julius Caesar" or "Gaius Julius Caesar" | "'He's around somewhere. He looks pretty down.'" | "Caesar is looking depressed" | -- |
| "Anas/duck" | "'Jupiter's new plaything? She's in the baths.'" | "Anas can be found in the baths" | -- |
| "Syra" | "'Seriously, wow, the slut to end all sluts.'" | "she's pretty impressed by Syra's sluttiness" | -- |
| "game/dice/table/figurine/figurines/die" | "'The Great Game! I've got a pretty big bet on you. Don't let me down.'" | "Eris is counting on you to win the game for her" | -- |
| "herself/eris/discordia/reward/immortality/sex/blowjob/fuck/fucking" | "'Patience, patience. Do your part, and I'll....do your part.'" | "Eris will reward you for completing her quest" | -- |
| "Mweru/bird" or "Mweru bird" | "'Yeah, somehow the original got lost, but we had that stuffed canary lying around.'" | "the stuffed canary is a stand-in for the real Mweru Bird figurine" | -- |
Instead of showing the Golden Banana to Divine Eris, try giving the Golden Banana to Divine Eris.
Instead of touching, rubbing, sucking, fucking, blowing, kissing, or wanking off Divine Eris, say "Eris shakes her head. 'You don't get your reward yet, little man. Finish the job.'"
Before asking Divine Eris about something:
if the topic understood matches "task/quest/hundred-eyed/golden/banana/discord", replace the topic understood with "Argus";
if the topic understood matches "one more task", replace the topic understood with "Argus";
if the topic understood matches "golden banana", replace the topic understood with "Argus";
if the topic understood matches "golden banana of discord", replace the topic understood with "Argus";
if the topic understood matches "hundred-eyed Argus", replace the topic understood with "Argus";
if the topic understood matches "Argus" and Divine Eris is not warned_about, instead try giving the Golden Banana to Divine Eris.
Before asking Divine Eris about "Argus" when Divine Eris is not warned_about:
say "Eris frowns, starts to say something, and then looks at the Golden Banana. You hold it out to her placatingly.[paragraph break]";
instead try giving the Golden Banana to Divine Eris.
Before giving the Golden Banana to Divine Eris:
if Divine Eris is not warned_about
begin;
say "Eris looks at the banana you are carrying and smiles. 'Thank you, Stiffy. I appreciate all your hard work in bringing that to me. Unfortunately, our plans have changed a little, and I have one more task for you: I want you to take that banana into the palace, and sodomize Argus with it. It's going to be a little difficult, because he's pretty vigilant, but I'll do my best to distract him. That bastard has a whole bunch of eyes, so if you can come up with more help to draw his attention, you'll want to.'[paragraph break]";
say "She pauses a moment and frowns. 'You'll probably need these in order to see once you're in the palace, with your weak mortal eyes.' She hands you a pair of sunglasses.[paragraph break]";
now the sunglasses are held by the player;
move scenery_eris to the Grand Palace;
say "'Anyway, just head up to him. I'll get his attention, and then when he's not looking, stick the Golden Banana up his ass and you will have completed my quest, and you will be rewarded, both with immortality, and with my special favor.' She winks saucily at you.";
now Divine Eris is warned_about;
otherwise;
say "Eris glances at you. 'That banana doesn't have Argus on the other end of it. Get on with it.'";
end if;
stop the action.
Before taking the Stiffy Makane figurine when the player is Stiffy Makane:
if the Stiffy Makane figurine is not warned_about
begin;
say "You start to reach for the figurine of yourself, and then you begin to think about the implications, and your head starts to hurt a little. You pause momentarily, wondering whether picking up the model of yourself is actually a good idea.";
now the Stiffy Makane figurine is warned_about;
stop the action;
otherwise;
consider the stack-overflow rule;
end if.
This is the stack-overflow rule:
say "As you reach for the figurine Eris screams, 'Stiffy! No! Stop!' but she's too late.[paragraph break]";
say "Your hand closes around the figurine and [run paragraph on]";
let T be 0;
let loop-exit be 200 plus a random number between 1 and 200;
while T < loop-exit
begin;
say "your hand closes around the figurine and [run paragraph on]";
increase T by 1;
end while;
say "[paragraph break][paragraph break][paragraph break]";
say "[fixed letter spacing]The multiverse has encountered an error and needs to close. We are sorry for the inconvenience.[variable letter spacing]";
say "[paragraph break][paragraph break][paragraph break]";
wait for any key;
stop the game abruptly.
Some sunglasses are ornaments. Understand "sunglass", "glass", "glasses", "shades", "shade", "oakleys", "ray-bans", "ray-ban", "spectacles", "specs", "smoked", "dark", "circle", "circles", "ovals", "wire", and "wires" as sunglasses. The description is "These sunglasses are circles of smoked glass in wire frames. They serve to make the world less bright when worn."