Stiffy Makane: Apocolocyntosis — 45 of 235

One of the Bruces and Drunken Bastard

Release 1

Part Two - "The Tavern"

The Seedy Tavern is a room. It is north of the Twisty Little Alley. The description is "This is an almost unimaginably seedy tavern. Wine, of the undigested, partially digested, and completely digested varieties, stains all visible surfaces. The exit is south." The Twisty Little Alley is outside from the Seedy Tavern. Instead of smelling the Seedy Tavern, try examining the piss.

The piss is scenery in the Seedy Tavern. The description is "Ugh." Understand "barf", "vomit", "puke", "pee", "shit", "feces", and "poop" as piss. Instead of doing anything other than examining with the piss, try examining the piss.

The scenery_wine is scenery. The description is "Ugh." Understand "wine" as scenery_wine. Instead of doing anything other than examining with the scenery_wine, try examining the scenery_wine. The printed name is "wine".

The bench is a supporter in the Seedy Tavern. The description is "The bench is about as stained as everything else in here." Instead of taking the bench: say "It's too large to carry. Why would you want to anyway?" Instead of smelling the bench: say "What a revolting idea." Instead of tasting the bench, try smelling the bench. Instead of touching the bench, say "You'd really rather not." It is enterable.

Some stentorian snores are scenery in the Seedy Tavern. The description is "Perfectly ordinary stentorian snores of passed-out drunkards." Instead of listening to the stentorian snores, try examining the stentorian snores. Instead of doing anything other than listening or examining with the stentorian snores, say "The snores, thankfully, are immaterial."

Rule for writing a paragraph about the bench:

if the Priest of Jupiter Virilis is on the bench

begin;

say "The Priest of Jupiter Virilis sways gently from side to side as he sits on a bench at a wooden table.";

now the Priest of Jupiter Virilis is mentioned;

otherwise;

say "A rough wooden bench rests on the dirty floor.";

now the bench is mentioned;

end if.

Rule for writing a paragraph about the table:

if the bottle of wine is on the table

begin;

say "A clay bottle of wine, adorned with a leering satyr, rests on a leaning table.";

now the bottle of wine is mentioned;

otherwise;

say "A battered table, leaning slightly, shakily stands near the center of the tavern.";

now the table is mentioned;

end if.

The table is a supporter in the Seedy Tavern. The description is "The table is about as stained as everything else in here." Instead of taking the table: say "It's much too large to carry, and you really have no need for a piss-and-barf-stained rough-hewn table." Instead of tasting the table, try smelling the bench. Instead of smelling the table, try smelling the bench. Instead of touching the table, try touching the bench. It is enterable.

The bottle of wine is a thing on the table. "A clay bottle, imprinted with the visage of a drunken satyr, squats on the table." The description is "A clay bottle filled, presumably, with cheap wine." Understand "bottle", "wine", and "clay" as bottle. Check taking the bottle of wine: if the priest is visible, instead say "The priest glowers so fiercely that you meekly retreat." The bottle of wine can be drinkable. The bottle of wine is drinkable. Check drinking the bottle of wine: instead try taking the bottle of wine. Check rolling the wine: instead say "That would just spill it." Check smelling the bottle of wine: instead try taking the bottle of wine.